Eu Acuso

30 de julho de 201730 de julho de 2017 MSX-Basic 0 comentários Inteligência, Jogos, Lógica, Raciocínio

Descubra Quem é o Culpado. Este é um jogo para testar a sua capacidade de dedução.

Teste o programa no WebMSX – The Online MSX Emulator

Você é o Inspetor Silva do DIC (Departamento de Investigações Criminais) e está sendo submetido a uma série de testes, que têm por objetivo avaliar sua coragem, persistência e capacidade de usar o computador em investigações criminais. Como não podemos reproduzir aqui as provas de coragem e persistência, vamos nos limitar ao teste de investigação por computador.
O computador tem a capacidade de gerar milhares de diferentes permutações a partir de um certo conjunto de dados. Em um piscar de olhos, ele seleciona um criminoso e uma série de características pessoais que o identificam perfeitamente. Você tem direito de interrogar uma testemunha do crime a respeito de seis dessas características, para isso, basta entrar no computador com o número correspondente à característica desejada, de acordo com a lista que aparece do lado esquerdo da tela. O computador então mostra as características dos diferentes suspeitos e a característica do criminoso, de acordo com o depoimento da testemunha. Se você souber escolher bem as perguntas, poderá descobrir facilmente o culpado!
Depois de fazer as seis perguntas, você entra com o número da pessoa que julga ser o criminoso. O computador então revela se você acertou ou não.

Fonte: Livro de Jogos em MSX
Editora: Lutécia
Autor: Jim Gregory (livro) – Andy (programa)
Ano: 1985
Digitação: Wilson e Willian Pilon – MSX Typer

Código fonte

1000 REM <<<< EU ACUSO - JIM/ANDY >>>>
1010 REM
1020 KEY OFF
1030 SCREEN 0,0,0:COLOR 15,4,4:WIDTH 36
1040 GOSUB 1350
1050 GOSUB 1560
1060 GOSUB 1700
1070 FOR G=1 TO 6
1080 GOSUB 2090
1090 NEXT G
1100 LOCATE 0,18:PRINT STRING$(39," ")
1110 LOCATE 0,13:PRINT "Agora entre com o numero da pessoa      que voce acha que cometeu o crime."
1120 PRINT "   A testemunha disse que .  .  .":PRINT
1130 RESTORE 1330
1140 FOR N=1 TO 10
1150 READ A$
1160 IF W(1)=N OR W(2)=N OR W(3)=N OR W(4)=N THEN PRINT "O criminoso";A$;" ";S$(S,N)
1170 NEXT N
1180 A$=INKEY$:IF A$<"1" OR A$>"4" THEN 1180
1190 CR=VAL(A$)
1200 FOR Y=12 TO 21:LOCATE 0,Y:PRINT STRING$(39," "):NEXT Y
1210 IF CR=S THEN 1290
1220 LOCATE 0,15:PRINT "Que vergonha,  Inspetor' Gibbs!         Esta rebaixado a Guarda Gibbs!"
1230 PLAY "l16fedc12c"
1240 PRINT:PRINT " O criminoso era o suspeito numero ";S;"!"
1250 LOCATE 0,20:PRINT "Aperte qualquer tecla para jogar de novo"
1260 A$=INKEY$:IF A$="" THEN 1260
1270 FOR N=0 TO 9:QW(N)=0:NEXT N
1280 GOTO 1050
1290 LOCATE 0,15:PRINT "Paarbens,Inspetor Gibbs !"
1300 PLAY"l16cdefcdefcdel2f"
1310 PRINT:PRINT "O senhor descobriu quem era o criminoso a partir das pistas disponiveis!"
1320 GOTO 1250
1330 DATA " era"," era"," era"," tinha cabelo"," tinha  cabelo"," estava de"," calcava"," tinha olhos"," tinha um nariz"," tinha uma"
1340 REM >>>> INICIALIZA€°O >>>>
1350 DIM S$(4,10)
1360 DIM W(4),QW(9)
1370 DIM L$(10,4)
1380 RESTORE 1450
1390 FOR N=1 TO 10
1400 FOR M=1 TO 4
1410 READ L$(N,M)
1420 NEXT M
1430 NEXT N
1440 RETURN
1450 DATA HOMEM,MULHER,HOMEM,MULHER
1460 DATA GORDO,MAGRO,FORTE,PALIDO
1470 DATA ALTO,GRANDE,BAIXO,PEQUENO
1480 DATA LISO,CURTO,CRESPO,LONGO
1490 DATA BRANCO,PRETO,LOURO,RUIVO
1500 DATA JEANS,MACACAO,CAPA,SHORTS
1510 DATA TAMANCO,BOTA,TENIS,GALOCHA
1520 DATA AZUIS,MARRONS,VERDES,PRETOS
1530 DATA ADUNCO,GRANDE,REGULAR,TORTO
1540 DATA PISTOLA,PINTA,FACA,MALA
1550 REM <<<< TELA >>>>
1560 NO=1: SCREEN 0:WIDTH 40
1570 FOR N=10 TO 34 STEP 8
1580 LOCATE N,0:PRINT NO
1590 NO=NO+1
1600 NEXT N
1610 RESTORE 1660
1620 FOR N=2 TO 11
1630 LOCATE 0,N
1640 READ A$:PRINT A$
1650 NEXT N
1660 DATA 0-SEXO,1-TIPO,2-ALTURA,3-CABELO,4-COR'',5-TRAJE,6-SAPATO,7-OLHOS,8-NARIZ,9-OUTROS
1670 LOCATE 0,18:PRINT "Escolha uma pista (0-9). . . ."
1680 RETURN
1690 REM <<<< ESCOLHA DOS SUSPEITOS >>>>
1700 S=INT(RND(-TIME)*4)+1
1710 FOR N=1 TO 4
1720 W(N)=0
1730 CH=0
1740 A=INT(RND(1)*10)+1
1750 FOR Q=1 TO 4
1760 IF W(Q)=A THEN CH=1
1770 NEXT Q
1780 IF CH=1 THEN 1730
1790 W(N)=A
1800 NEXT N
1810 FOR N=1 TO 10
1820 FOR Q=1 TO 4
1830 A=INT(RND(1)*4)+1
1840 S$(Q,N)=L$(N,A)
1850 NEXT Q
1860 NEXT N
1870 N=W(1):GOSUB 1900:N=W(2):GOSUB 1900
1880 N=W(3):GOSUB 1900:N=W(3):GOSUB 1980
1890 RETURN
1900 A=INT(RND(1)*4)+1
1910 S$(S,N)=L$(N,A)
1920 T=S+2:IF T>4 THEN T=T-4
1930 S$(T,N)=L$(N,A)
1940 IF A<>1 THEN B=A-1 ELSE B=4
1950 T=T-2:IF T<1 THEN T=T+4
1960 S$(T,N)=L$(N,B)
1970 RETURN
1980 A=INT(RND(1)*4)+1
1990 S$(T,N)=L$(N,A)
2000 IF S<>1 THEN T=S-1 ELSE T=4
2010 S$(T,N)=L$(N,A)
2020 IF A<>4 THEN B=A+1 ELSE B=1
2030 T=T-1:IF T=0 THEN T=4
2040 S$(T,N)=L$(N,B)
2050 T=T-1:IF T=0 THEN T=4
2060 S$(T,N)=L$(N,B)
2070 RETURN
2080 REM <<<< ESCOLHA DAS PISTAS >>>>
2090 A$=INKEY$:IF A$="" THEN 2090
2100 QW=VAL(A$)
2110 IF QW<0 OR QW>9 OR QW(QW)<>0 THEN 2090
2120 PLAY "l8f":QW(QW)=1:QW=QW+1
2130 FOR PE=1 TO 4
2140 LOCATE 8+(PE*8-7),1+QW
2150 PRINT S$(PE,QW);
2160 NEXT PE
2170 RETURN

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

1000 REM <<<< EU ACUSO - JIM/ANDY >>>>

1010 REM

1020 KEY OFF

1030 SCREEN 0,0,0:COLOR 15,4,4:WIDTH 36

1040 GOSUB 1350

1050 GOSUB 1560

1060 GOSUB 1700

1070 FOR G=1 TO 6

1080 GOSUB 2090

1090 NEXT G

1100 LOCATE 0,18:PRINT STRING$(39," ")

1110 LOCATE 0,13:PRINT "Agora entre com o numero da pessoa que voce acha que cometeu o crime."

1120 PRINT " A testemunha disse que . . .":PRINT

1130 RESTORE 1330

1140 FOR N=1 TO 10

1150 READ A$

1160 IF W(1)=N OR W(2)=N OR W(3)=N OR W(4)=N THEN PRINT "O criminoso";A$;" ";S$(S,N)

1170 NEXT N

1180 A$=INKEY$:IF A$<"1" OR A$>"4" THEN 1180

1190 CR=VAL(A$)

1200 FOR Y=12 TO 21:LOCATE 0,Y:PRINT STRING$(39," "):NEXT Y

1210 IF CR=S THEN 1290

1220 LOCATE 0,15:PRINT "Que vergonha, Inspetor' Gibbs! Esta rebaixado a Guarda Gibbs!"

1230 PLAY "l16fedc12c"

1240 PRINT:PRINT " O criminoso era o suspeito numero ";S;"!"

1250 LOCATE 0,20:PRINT "Aperte qualquer tecla para jogar de novo"

1260 A$=INKEY$:IF A$="" THEN 1260

1270 FOR N=0 TO 9:QW(N)=0:NEXT N

1280 GOTO 1050

1290 LOCATE 0,15:PRINT "Paarbens,Inspetor Gibbs !"

1300 PLAY"l16cdefcdefcdel2f"

1310 PRINT:PRINT "O senhor descobriu quem era o criminoso a partir das pistas disponiveis!"

1320 GOTO 1250

1330 DATA " era"," era"," era"," tinha cabelo"," tinha cabelo"," estava de"," calcava"," tinha olhos"," tinha um nariz"," tinha uma"

1340 REM >>>> INICIALIZA€°O >>>>

1350 DIM S$(4,10)

1360 DIM W(4),QW(9)

1370 DIM L$(10,4)

1380 RESTORE 1450

1390 FOR N=1 TO 10

1400 FOR M=1 TO 4

1410 READ L$(N,M)

1420 NEXT M

1430 NEXT N

1440 RETURN

1450 DATA HOMEM,MULHER,HOMEM,MULHER

1460 DATA GORDO,MAGRO,FORTE,PALIDO

1470 DATA ALTO,GRANDE,BAIXO,PEQUENO

1480 DATA LISO,CURTO,CRESPO,LONGO

1490 DATA BRANCO,PRETO,LOURO,RUIVO

1500 DATA JEANS,MACACAO,CAPA,SHORTS

1510 DATA TAMANCO,BOTA,TENIS,GALOCHA

1520 DATA AZUIS,MARRONS,VERDES,PRETOS

1530 DATA ADUNCO,GRANDE,REGULAR,TORTO

1540 DATA PISTOLA,PINTA,FACA,MALA

1550 REM <<<< TELA >>>>

1560 NO=1: SCREEN 0:WIDTH 40

1570 FOR N=10 TO 34 STEP 8

1580 LOCATE N,0:PRINT NO

1590 NO=NO+1

1600 NEXT N

1610 RESTORE 1660

1620 FOR N=2 TO 11

1630 LOCATE 0,N

1640 READ A$:PRINT A$

1650 NEXT N

1660 DATA 0-SEXO,1-TIPO,2-ALTURA,3-CABELO,4-COR'',5-TRAJE,6-SAPATO,7-OLHOS,8-NARIZ,9-OUTROS

1670 LOCATE 0,18:PRINT "Escolha uma pista (0-9). . . ."

1680 RETURN

1690 REM <<<< ESCOLHA DOS SUSPEITOS >>>>

1700 S=INT(RND(-TIME)*4)+1

1710 FOR N=1 TO 4

1720 W(N)=0

1730 CH=0

1740 A=INT(RND(1)*10)+1

1750 FOR Q=1 TO 4

1760 IF W(Q)=A THEN CH=1

1770 NEXT Q

1780 IF CH=1 THEN 1730

1790 W(N)=A

1800 NEXT N

1810 FOR N=1 TO 10

1820 FOR Q=1 TO 4

1830 A=INT(RND(1)*4)+1

1840 S$(Q,N)=L$(N,A)

1850 NEXT Q

1860 NEXT N

1870 N=W(1):GOSUB 1900:N=W(2):GOSUB 1900

1880 N=W(3):GOSUB 1900:N=W(3):GOSUB 1980

1890 RETURN

1900 A=INT(RND(1)*4)+1

1910 S$(S,N)=L$(N,A)

1920 T=S+2:IF T>4 THEN T=T-4

1930 S$(T,N)=L$(N,A)

1940 IF A<>1 THEN B=A-1 ELSE B=4

1950 T=T-2:IF T<1 THEN T=T+4

1960 S$(T,N)=L$(N,B)

1970 RETURN

1980 A=INT(RND(1)*4)+1

1990 S$(T,N)=L$(N,A)

2000 IF S<>1 THEN T=S-1 ELSE T=4

2010 S$(T,N)=L$(N,A)

2020 IF A<>4 THEN B=A+1 ELSE B=1

2030 T=T-1:IF T=0 THEN T=4

2040 S$(T,N)=L$(N,B)

2050 T=T-1:IF T=0 THEN T=4

2060 S$(T,N)=L$(N,B)

2070 RETURN

2080 REM <<<< ESCOLHA DAS PISTAS >>>>

2090 A$=INKEY$:IF A$="" THEN 2090

2100 QW=VAL(A$)

2110 IF QW<0 OR QW>9 OR QW(QW)<>0 THEN 2090

2120 PLAY "l8f":QW(QW)=1:QW=QW+1

2130 FOR PE=1 TO 4

2140 LOCATE 8+(PE*8-7),1+QW

2150 PRINT S$(PE,QW);

2160 NEXT PE

2170 RETURN

Compartilhe: