Banho de Palavras

30 de julho de 201730 de julho de 2017 MSX-Basic 0 comentários Inteligência, Jogos, Lógica, Raciocínio

Decifra-me ou eu te Molho! Este jogo é uma versão mais divertida, menos cruel, do conhecido jogo da forca.

Teste o programa no WebMSX – The Online MSX Emulator

Se o jogador não consegue descobrir a palavra depois de um número razoável de tentativas, as próprias letras erradas o empurram para dentro d’água!
As palavras podem ter até oito letras e não podem conter hifens. O programa original tem 60 palavras, mas não é difícil ampliar a lista ou trocar as palavras por outras. Quando o jogador acerta uma letra, ela aparece na posição que ocupava na palavra. Quando a letra está errada, o jogador é empurrado na direção da piscina. Quando a palavra é completada a tempo, o jogador volta à posição inicial e o jogo começa de novo com outra palavra.
Quando o jogador não consegue descobrir a palavra, ela não é mostrada. Como as palavras são escolhidas ao acaso, a mesma palavra pode voltar a aparecer mais tarde.

Fonte: Livro de Jogos em MSX
Editora: Lutécia
Autor: Jim Gregory (livro) – Issi (programa)
Ano: 1985
Digitação: Wilson e Willian Pilon – MSX Typer

Código fonte

1000 REM <<<< BANHO DE PALAVRAS - ISSI >>>>
1010 MAXFILES=2:OPEN "grp:s" FOR OUTPUT AS 1
1020 GOSUB 1470
1030 W=INT(RND(-TIME)*60)+1
1040 W$=D$(W)
1050 GOSUB 1280
1060 GOSUB 1680
1070 FLAG=0
1080 IF T$=W$ THEN GOTO 1150
1090 IF LEN(G$)=10 THEN GOTO 1120
1100 GOTO 1060
1110 REM <<<< PERDE >>>>
1120 GOSUB 1520
1130 GOSUB 1250
1140 REM <<<< GANHA >>>>
1150 OCT=8
1160 IF G$="" THEN GOTO 1230
1170 FOR N=LEN(G$) TO 1 STEP -1
1180 G$=RIGHT$(G$,N-1)
1190 M$="s11l64o"+STR$(OCT)+"c":PLAY M$
1200 GOSUB 1810:PRINT " "
1210 FOR W=1 TO 250:NEXT W
1220 NEXT N
1230 PRESET (98,24):PRINT #1," PARABENS!"
1240 PRESET (98,32):PRINT #1,"-----------"
1250 A$=INKEY$:IF A$="" THEN 1250
1260 BEEP:GOTO 1030
1270 REM <<<< TELA >>>>
1280 SCREEN 2,0,0:KEY OFF
1290 COLOR 15,1,1:CLS
1300 PRESET (74,0):PRINT #1,"BANHO DE PALAVRAS":COLOR 3
1310 A$="":FOR N=1 TO 8:A$=A$+CHR$(&HCB)+CHR$(&HCC):NEXT N
1320 PRESET (76,10):PRINT #1,A$
1330 PRESET (24,56):COLOR 13:O$=CHR$(1)+CHR$(&HCC):PRINT #1,O$
1340 LINE (128,100)-(208,160),4,BF
1350 LINE (120,88)-(128,100),4
1360 LINE (216,88)-(208,100),4
1370 LINE (0,65)-(104,65),14
1380 LINE -STEP(20,20),14
1390 COLOR 11:PRESET (10,80):PRINT #1,"Palavra:"
1400 PRESET (40,120):T$="":G$=""
1410 COLOR 5:FOR N=1 TO LEN(W$)
1420 PRINT #1,"-";:T$=T$+" "
1430 NEXT N
1440 PRESET (8,152):PRINT #1,"Letra ?"
1450 RETURN
1460 REM <<<< INICIALIZACAO >>>>
1470 RESTORE 1870
1480 DIM D$(60)
1490 FOR N=1 TO 60:READ D$(N):NEXT N
1500 RETURN
1510 REM <<<< TCHIBUM! >>>>
1520 FOR N=106 TO 152 STEP 2
1530 COLOR 1:PRESET (N-2,N-50)
1540 PRINT #1,CHR$(1)+CHR$(&HCB)
1550 COLOR 9:PRESET (N,N-48)
1560 PRINT #1,CHR$(1)+CHR$(&HCB);
1570 NEXT N
1580 RESTORE 1660
1590 FOR N=6 TO 13:READ A:SOUND N,A:NEXT N
1600 LINE -STEP(-8,0),4
1610 FOR I=1 TO 15:J=-RND(-TIME)*20:K=RND(-TIME)*40-20
1620 LINE -STEP(K,J),4:LINE -STEP(-K,-J),4
1630 NEXT I
1640 FOR W=1 TO 500:NEXT W
1650 RETURN
1660 DATA 15,135,16,16,16,0,16,0
1670 REM <<<< ENTRADA DE DADOS >>>>
1680 A$=INKEY$:IF A$="" THEN GOTO 1680
1690 A$=CHR$(ASC(A$) AND 223):PLAY "o4s11l16c"
1700 IF A$<"A" OR A$>"Z" THEN GOTO 1680
1710 FL=0:COLOR 9
1720 FOR N=1 TO LEN(W$)
1730 IF MID$(W$,N,1)=A$ THEN PRESET ((N+4)*8,112):PRINT #1,A$:MID$(T$,N,1)=A$:FL=1
1740 NEXT N
1750 IF FL=1 THEN PLAY "gab":RETURN
1760 FL=0:FOR M=1 TO LEN(G$)
1770 IF MID$(G$,M,1)=A$ THEN FL=1
1780 NEXT M
1790 IF FL=1 THEN RETURN
1800 G$=A$+G$
1810 PRESET (24,56):COLOR 1:PRINT #1,O$
1820 PRESET (24,56):COLOR 13
1830 IF LEN(G$)/2=INT(LEN(G$)/2) THEN M=&HCB ELSE M=&HCC
1840 O$=G$+CHR$(1)+CHR$(M):PRINT #1,O$;
1850 RETURN
1860 REM <<<< DADOS >>>>
1870 DATA ZUMBI,REPTO,BEZERRO,LIBELO,ASCO,GUAPO,COLDRE,MURRO,HIATO,JOVEM
1880 DATA QUARTEL,MASTIM,BIGORNA,HONESTO,ROBALO,GRAVIOLA,FICHA,JARRA,COLAPSO,POSTE
1890 DATA FEIXE,BRILHAR,ANIMAL,SORTE,PIADA,MIASMA,BRUSCO,CARPA,HORTO,SUNGA
1900 DATA BOLDO,PORTO,FELIZ,ISTMO,CRESPO,PLANTA,ANZOL,TURVO,CRIVO,DENGUE
1910 DATA GORDO,GRANEL,LERDO,ALGOZ,TRIAGEM,GRAVAME,MAXIXE,CHUCHU,NABABO,OSTRA
1920 DATA TRAVA,VESTAL,BESTIAL,REPOUSO,RAINHA,ALTAR,MODESTO,QUIABO,BOSQUE,LESMA

1000 REM <<<< BANHO DE PALAVRAS - ISSI >>>>

1010 MAXFILES=2:OPEN "grp:s" FOR OUTPUT AS 1

1020 GOSUB 1470

1030 W=INT(RND(-TIME)*60)+1

1040 W$=D$(W)

1050 GOSUB 1280

1060 GOSUB 1680

1070 FLAG=0

1080 IF T$=W$ THEN GOTO 1150

1090 IF LEN(G$)=10 THEN GOTO 1120

1100 GOTO 1060

1110 REM <<<< PERDE >>>>

1120 GOSUB 1520

1130 GOSUB 1250

1140 REM <<<< GANHA >>>>

1150 OCT=8

1160 IF G$="" THEN GOTO 1230

1170 FOR N=LEN(G$) TO 1 STEP -1

1180 G$=RIGHT$(G$,N-1)

1190 M$="s11l64o"+STR$(OCT)+"c":PLAY M$

1200 GOSUB 1810:PRINT " "

1210 FOR W=1 TO 250:NEXT W

1220 NEXT N

1230 PRESET (98,24):PRINT #1," PARABENS!"

1240 PRESET (98,32):PRINT #1,"-----------"

1250 A$=INKEY$:IF A$="" THEN 1250

1260 BEEP:GOTO 1030

1270 REM <<<< TELA >>>>

1280 SCREEN 2,0,0:KEY OFF

1290 COLOR 15,1,1:CLS

1300 PRESET (74,0):PRINT #1,"BANHO DE PALAVRAS":COLOR 3

1310 A$="":FOR N=1 TO 8:A$=A$+CHR$(&HCB)+CHR$(&HCC):NEXT N

1320 PRESET (76,10):PRINT #1,A$

1330 PRESET (24,56):COLOR 13:O$=CHR$(1)+CHR$(&HCC):PRINT #1,O$

1340 LINE (128,100)-(208,160),4,BF

1350 LINE (120,88)-(128,100),4

1360 LINE (216,88)-(208,100),4

1370 LINE (0,65)-(104,65),14

1380 LINE -STEP(20,20),14

1390 COLOR 11:PRESET (10,80):PRINT #1,"Palavra:"

1400 PRESET (40,120):T$="":G$=""

1410 COLOR 5:FOR N=1 TO LEN(W$)

1420 PRINT #1,"-";:T$=T$+" "

1430 NEXT N

1440 PRESET (8,152):PRINT #1,"Letra ?"

1450 RETURN

1460 REM <<<< INICIALIZACAO >>>>

1470 RESTORE 1870

1480 DIM D$(60)

1490 FOR N=1 TO 60:READ D$(N):NEXT N

1500 RETURN

1510 REM <<<< TCHIBUM! >>>>

1520 FOR N=106 TO 152 STEP 2

1530 COLOR 1:PRESET (N-2,N-50)

1540 PRINT #1,CHR$(1)+CHR$(&HCB)

1550 COLOR 9:PRESET (N,N-48)

1560 PRINT #1,CHR$(1)+CHR$(&HCB);

1570 NEXT N

1580 RESTORE 1660

1590 FOR N=6 TO 13:READ A:SOUND N,A:NEXT N

1600 LINE -STEP(-8,0),4

1610 FOR I=1 TO 15:J=-RND(-TIME)*20:K=RND(-TIME)*40-20

1620 LINE -STEP(K,J),4:LINE -STEP(-K,-J),4

1630 NEXT I

1640 FOR W=1 TO 500:NEXT W

1650 RETURN

1660 DATA 15,135,16,16,16,0,16,0

1670 REM <<<< ENTRADA DE DADOS >>>>

1680 A$=INKEY$:IF A$="" THEN GOTO 1680

1690 A$=CHR$(ASC(A$) AND 223):PLAY "o4s11l16c"

1700 IF A$<"A" OR A$>"Z" THEN GOTO 1680

1710 FL=0:COLOR 9

1720 FOR N=1 TO LEN(W$)

1730 IF MID$(W$,N,1)=A$ THEN PRESET ((N+4)*8,112):PRINT #1,A$:MID$(T$,N,1)=A$:FL=1

1740 NEXT N

1750 IF FL=1 THEN PLAY "gab":RETURN

1760 FL=0:FOR M=1 TO LEN(G$)

1770 IF MID$(G$,M,1)=A$ THEN FL=1

1780 NEXT M

1790 IF FL=1 THEN RETURN

1800 G$=A$+G$

1810 PRESET (24,56):COLOR 1:PRINT #1,O$

1820 PRESET (24,56):COLOR 13

1830 IF LEN(G$)/2=INT(LEN(G$)/2) THEN M=&HCB ELSE M=&HCC

1840 O$=G$+CHR$(1)+CHR$(M):PRINT #1,O$;

1850 RETURN

1860 REM <<<< DADOS >>>>

1870 DATA ZUMBI,REPTO,BEZERRO,LIBELO,ASCO,GUAPO,COLDRE,MURRO,HIATO,JOVEM

1880 DATA QUARTEL,MASTIM,BIGORNA,HONESTO,ROBALO,GRAVIOLA,FICHA,JARRA,COLAPSO,POSTE

1890 DATA FEIXE,BRILHAR,ANIMAL,SORTE,PIADA,MIASMA,BRUSCO,CARPA,HORTO,SUNGA

1900 DATA BOLDO,PORTO,FELIZ,ISTMO,CRESPO,PLANTA,ANZOL,TURVO,CRIVO,DENGUE

1910 DATA GORDO,GRANEL,LERDO,ALGOZ,TRIAGEM,GRAVAME,MAXIXE,CHUCHU,NABABO,OSTRA

1920 DATA TRAVA,VESTAL,BESTIAL,REPOUSO,RAINHA,ALTAR,MODESTO,QUIABO,BOSQUE,LESMA

Compartilhe:

julho 2017
D	S	T	Q	Q	S	S
				ago »
						1
2	3	4	5	6	7	8
9	10	11	12	13	14	15
16	17	18	19	20	21	22
23	24	25	26	27	28	29
30	31